WWII Attack! from Pearl Harbor to Potsdam/WWII Attack - From Pearl Harbor to Potsdam - Disc 3.iso/pc/us/shared.cst/00029_Script_29

Text File | 1999-11-23 | 10KB | 300 lines

on morph total, delay, downSound, upSound
  if stringP(downSound) then
    puppetsound downSound
  end if
  put the castnum of sprite the clickon into this
  set wait to the timer
  repeat with variable = 1 to total - 1
    repeat while wait > the timer
    end repeat
    set the castnum of sprite the clickon to this + variable
    updatestage
    set wait to the timer + delay
  end repeat
  repeat while the stillDown or soundBusy (1)
  end repeat
  if stringP(upSound) then
    puppetSound(upSound)
  end if
  put the castnum of sprite the clickon into this
  set wait to the timer
  repeat with variable = 1 to total - 1
    repeat while wait > the timer
    end repeat
    set the castnum of sprite the clickon to this - variable
    updatestage
    set wait to the timer + delay
  end repeat
  repeat while soundBusy (1)
  end repeat
  puppetSound 0
end

on click downSound, upSound

  set variable to the castNum of sprite the clickon
  set the castNum of sprite the clickon to variable + 1
  updateStage
  repeat while the stillDown or soundBusy (1)
  end repeat
    set the castNum of sprite the clickon to variable
  updateStage
  repeat while soundBusy (1)
  end repeat
  puppetSound 0
  updateStage
end

----------------------------------------------------------
-- This Lingo Script has been written by Greg S. Callen --
--                    for statômedia                    --
--    © Copyright 1992 statômedia All Rights Reseved    --
----------------------------------------------------------

on jogger total, downSound
  if stringP(downSound) then
    puppetSound downSound
  end if
  set myNumber to the castNum of sprite the clickon
  repeat while the stillDown                                   -- Track mouse
    set vert to the mouseV - the locV of sprite the clickon    -- Vertical differance
    set horz to the mouseH - the locH of sprite the clickon    -- Horzontal differance
    if horz<0 then                                             -- If the pointer is left of center
      set angle to 3.1415926 * 3 / 2                           -- go to the large half of circle.
      set offset to -0.001
    else                                                       -- If the pointer is elsewhere
      set angle to 3.1415926 / 2                               -- go to the small half of circle.
      set offset to +0.001
    end if
    put aTan(vert/(offset + horz)) + angle into angle          -- Arctangent in radians
    set angle to integer(angle * (total - 1) / 6.2831852 + 1)  -- Radians to cast word two
    set snap to word 1 of the name of ¨
        cast the castNum of sprite the clickon                 -- Cast name word one
    put " " after snap                                         -- Padded words
    put angle after snap                                       -- Cast name word two
    set the castNum of sprite the clickon¨
        to the number of cast snap                             -- Change the cast member
    updateStage
  end repeat                                                   -- thumb back if mouse is still down
  set the castNum of sprite the clickon to myNumber
  puppetSound 0
  updateStage
end

on motion new, offsetH, offsetV, downSound, upSound
  if stringP(downSound) then
    puppetSound downSound
  end if
  put the castnum of sprite the clickon into variable
  put the locH of sprite the clickOn into horz
  put the locV of sprite the clickOn into vert
  set the castnum of sprite the clickon to variable + new
  set the locH of sprite the clickOn to horz + offsetH
  set the locV of sprite the clickOn to vert + offsetV
  updatestage
  repeat while the stillDown or soundBusy (1)
  end repeat
  if stringP(upSound) then
    puppetSound upSound
  end if
  set the castnum of sprite the clickon to variable
  set the locH of sprite the clickOn to horz
  set the locV of sprite the clickOn to vert
  updateStage
  repeat while soundBusy (1)
  end repeat
  puppetSound 0
  updateStage
end

on dial total, downSound
  if stringP(downSound) then
    puppetSound downSound
  end if
  repeat while the stillDown                                   -- Track mouse
    set vert to the mouseV - the locV of sprite the clickon    -- Vertical differance
    set horz to the mouseH - the locH of sprite the clickon    -- Horzontal differance
    if horz<0 then                                             -- If the dial is left of center
      set angle to 3.1415926 * 3 / 2                           -- go to the large half of circle.
      set offset to -0.001
    else                                                       -- If the dial is elsewhere
      set angle to 3.1415926 / 2                               -- go to the small half of circle.
      set offset to +0.001
    end if
    put aTan(vert/(offset + horz)) + angle into angle          -- Arctangent in radians
    set angle to integer(angle * (total - 1) / 6.2831852 + 1)  -- Radians to cast word two
    set snap to word 1 of the name of ¨
        cast the castNum of sprite the clickon                 -- Cast name word one
    put " " after snap                                         -- Padded words
    put angle after snap                                       -- Cast name word two
    set the castNum of sprite the clickon¨
        to the number of cast snap                             -- Change the cast member
    updateStage
  end repeat                                                   -- thumb back if mouse is still down
  puppetSound 0
end

on toggle top
  set myName to word 1 of the name of cast the castNum of sprite the clickon
  repeat while the stillDown
    set vert to the locV of sprite the clickon - the mouseV
    set vpos to vert / 5
    if vpos > top then
      set vpos to top
    end if
    if vpos < -top then
      set vpos to -top
    end if
    put myName && vpos into snap
    set the castNum of sprite the clickon to the number of cast snap
    updateStage
  end repeat
  if value(word 2 of snap) < 0 then
    set vpos to -top
  else
    set vpos to top
  end if
  put myName && vpos into snap
  set the text of cast "string" to snap
  set the castNum of sprite the clickon to the number of cast snap
  updateStage
end

on switch total, delay, downSound
  if stringP(downSound) then
    puppetSound downSound
  end if
  set variable to the castNum of sprite the clickon
  repeat with n=1 to (abs(total) - 1)
    set wait to the timer + delay
    if total > 0 then
      set the castNum of sprite the clickon to variable + n
    else
      set the castNum of sprite the clickon to variable - n
    end if
    updateStage
    repeat while wait > the timer
    end repeat
  end repeat
  repeat while soundBusy (1)
  end repeat
  puppetSound 0
end

on loop total, delay, soundLoop
  if stringP(soundLoop) then
    puppetSound soundLoop
  end if
  set myNumber to the castNum of sprite the clickon
  repeat while the stillDown
    repeat with n=1 to total - 1
      set wait to the timer + delay
      set the castNum of sprite the clickon to myNumber + n
      updateStage
      repeat while wait > the timer
      end repeat
    end repeat
    set the castNum of sprite the clickon to myNumber
    updateStage
  end repeat
  puppetSound 0
end

on pointer total, downSound
  if stringP(downSound) then
    puppetSound downSound
  end if
  repeat while the stillDown
    set vert to the mouseV - the locV of sprite the clickon
    set horz to the mouseH - the locH of sprite the clickon
    set angle to 3.1415926 / 4
    put aTan (horz / (0.001 - vert)) + angle into angle
    set angle to integer(angle * (total - 1) / 3.1415926 * 2.0 + 1)
    if angle > total then set angle to total
    if angle < 1 then set angle to 1
    if vert < 0 then
      set snap to word 1 of the name of cast the castNum of sprite the clickon
      put " " after snap
      put angle after snap
      set the castNum of sprite the clickon to the number of cast snap
      updateStage
    end if
  end repeat
  puppetSound 0
  updateStage
end

on steps total, delay, downSound
  if stringP(downSound) then
    puppetSound downSound
  end if
  put the castNum of sprite the clickon into myCast
  put the name of cast myCast into myName
  put word 2 of myName into myNumber
  put word 1 of myName into myName
  repeat while the stillDown
    set wait to the timer + delay
    set myNumber to value(myNumber) + 1
    if myNumber > total then
      set myNumber to 1
    end if
    put myName && myNumber into myCast
    set the castNum of sprite the clickon to the number of cast myCast
    set the locH of sprite the clickon to the mouseH
    set the locV of sprite the clickon to the mouseV
    updateStage
    repeat while wait > the timer
    end repeat
  end repeat
  puppetSound 0
  updateStage
end

on thumb total, delay, downSound
  if stringP(downSound) then
    puppetSound downSound
  end if
  put the castNum of sprite the clickon into myCast
  put the name of cast myCast into myName
  put word 2 of myName into myNumber
  put word 1 of myName into myName
  repeat while the stillDown
    set wait to the timer + delay
    if the mouseV > the locV of sprite the clickon then
      set myNumber to value(myNumber) + 1
      if myNumber > total then
        set myNumber to 1
      end if
    else
      set myNumber to value(myNumber) - 1
      if myNumber < 1 then
        set myNumber to total
      end if
    end if
    put myName && myNumber into myCast
    set the castNum of sprite the clickon to the number of cast myCast
    updateStage
    repeat while wait > the timer
    end repeat
  end repeat
  puppetSound 0
  updateStage
end

on flash downSound, upSound
  if stringP(downSound) then
    puppetSound downSound
  end if
  set the ink of sprite the clickon to 4
  updatestage
  repeat while the stillDown or soundBusy(1)
  end repeat
  if stringP(upSound) then
    puppetSound upSound
  end if
  set the ink of sprite the clickon to 36
  updatestage
  repeat while soundBusy(1)
  end repeat
  puppetSound 0
end